10 DIM serie, i, l, x, dist(24), fret(24)
100 CLS
110 PRINT : PRINT " Guitar Fret Spacing Computer " : PRINT
120 INPUT " Scale Guitar Length (distance Fret #0 - Bridge) = ",l

200 REM COMPUTING  serie
210 serie = 0
220 for i = 0 To 11
230 serie = serie + 2 ^ (-i / 12)
240 next i

300 REM COMPUTING x
310 x = l * (1 / 2) * (1 / serie)

400 REM COMPUTING  array  dist(n)
410 dist(0) = 0
420 dist(1) = x
430 for i = 2 To 24
440 dist(i) = dist(i - 1) / 2 ^ (1 / 12)
450 next i

500 REM COMPUTING  array  fret(n)
510 fret(0) = 0
520 for i = 1 To 24
530 fret(i) = fret(i - 1) + dist(i)
540 next i

600 REM OUTPUT RESULTS
610 locate 6,2 : print "Fret"
620 locate 6,8 : print "Dist from prev"
630 locate 6,24 : print "Dist from neck"
640 locate 6,40 : print "Fret"
650 locate 6,46 : print "Dist from prev"
660 locate 6,62 : print "Dist from neck"

700 for i = 0 to 12
710 locate i+8,2 : print i
720 locate i+8,8 : print dist(i)
730 locate i+8,24 : print fret(i)
740 next i

800 for i = 12 to 24
810 locate i+8-12,40 : print i
820 locate i+8-12,46 : print dist(i)
830 locate i+8-12,62 : print fret(i)
840 next i
850 print : print "(c) Alberto Orlandini - Dedicated to Brian May"